带联网功能的RFID宿舍门禁(四)-NodeMCU网站与RC522共同控制舵机转动

带联网功能的RFID宿舍门禁项目目录

我有点厉害，这个系列的第一篇文章都没发出去，就完成了，不过还没装上门就是了，还能再水一篇，不错。
不过这个项目纯粹是为了混过课程作业的，没有考虑任何实际使用情况。
好气哦，早上能用的东西晚上就坏了，读卡的坏了，就剩个联网控制。
还有更气的，新买的读卡器只能读一次卡。

成品效果

将保存通行卡UID的程序烧录进Nano开发板，如果不知道UID，可以使用串口调试工具连接上开发板，刷卡后会显示UID，代码在下方Nano的这部分代码中：if(i==USER_NUM){ // 若i等于通行用户数量，则上层循环未找到通行卡。

之后，按下面表格的线路连接各模块，并接上开启微电流后的充电宝（防止电流过大烧坏），此时电路准备就绪，可开始工作。

刷卡后，Nano板会控制舵机转动，实现开门效果。

将任意主机连入ESP8266Web热点，进入网站192.168.4.1，点击Click，NodeMCU会发送信号给Nano板，并转动舵机开门。
(通信网站的获取可参考这篇文章的最后一部分：带联网功能的RFID宿舍门禁(二)-ESP8266利用arduino使用AP模式建立简单服务器)

舵机转动180度后转回，需要更改请参考这篇代码部分的说明：带联网功能的RFID宿舍门禁(三)-通过Arduino对RC522刷卡控制舵机转动开门。

材料

除了充电宝，其他材料的费用总和大概45元。

连线

Arduino Nano烧录平台

Arduino 1.8.13
开发板：Arduino Nano
处理器：ATmega328P (Old Bootloader)

Arduino Nano代码

/* 作者:MWHLS,主页MWHLS.TOP
 * 链接：http://mwhls.top/?p=659
 * 因为使用的不是SERVO.H库，舵机的PWM控制端口并不局限于9/10两个端口，且也不局限于仅控制两个舵机。
 * 通行卡的存储使用二维数组，将卡的UID转为十进制保存。
 * 卡的对比使用for函数遍历二维数组，对比UID是否相同。
 * 舵机启动由舵机控制变量servoRun控制，若值为1，则启动，其余不运行。
 * 接受到NodeMCU传来的信号时，舵机控制变量置1。
 * 发现通行卡时，舵机控制变量置1。
 * 参考文章：
 * 网页控制：https://blog.csdn.net/qq_46292418/article/details/106605366
 * I2C通信：https://blog.csdn.net/qq_44506730/article/details/90578507
 * RC522读卡：https://blog.csdn.net/leytton/article/details/73480974
 * 舵机控制：https://blog.csdn.net/sss_369/article/details/52894347
 */ 

#include <SPI.h>
#include <MFRC522.h>
#include <Wire.h>              //使用Wire.h进行I2C通信

#define SS_PIN 10
#define RST_PIN 9
#define SERVO_PIN 8
#define USER_NUM 3

byte servoRun = 0;              // 舵机控制变量。
MFRC522 rfid(SS_PIN, RST_PIN);  // 实例化类
byte userCard[USER_NUM][4] = {  // 通行卡存储数组。
  {28,   184,  119,  33},
  {249,  231,  71,   179},
  {109,  242,  234,  235}
};

void setup() { 
  Serial.begin(9600);           // 波特率设置
  SPI.begin();                  // 初始化SPI总线
  rfid.PCD_Init();              // 初始化 MFRC522 
  pinMode(SERVO_PIN, OUTPUT);   // 舵机控制端口。
  Wire.begin(8);                // 设置与NodeMCU的通信I2C端口。
  Wire.onReceive(receiveEvent); // 信号接受处理。
}

void loop() {
  if(servoRun == 1){            // 舵机运行变量若为1，则运行。
    servoControl();             // 舵机控制函数。
  }

  if ( ! rfid.PICC_IsNewCardPresent()) return;       // 找卡
  if ( ! rfid.PICC_ReadCardSerial())   return;       // 验证NUID是否可读
  MFRC522::PICC_Type piccType = rfid.PICC_GetType(rfid.uid.sak);
  if (piccType != MFRC522::PICC_TYPE_MIFARE_MINI &&  // 检查是否MIFARE卡类型
    piccType != MFRC522::PICC_TYPE_MIFARE_1K &&
    piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
    Serial.println("Can identify this card!");
    return;
  }

  byte i;
  for (i=0; i<USER_NUM;  i++){    // 判断卡是否为通行卡。
    byte i2;
    for(i2=0;  i2<4; i2++){       // 遍历userCard中所有卡。
      if(rfid.uid.uidByte[i2] != userCard[i][i2]) break;  
    }                             // break时，表示此卡不是通行卡。
    if(i2 == 4){                  // i2为4，表示此卡的四位值都验证通过。
      Serial.println("Find an accessful card.");  // 输出成功信息。
      servoRun = 1;               // 将开门变量置1。
      break;                      // 已找到通行卡，跳出循环。
    }
  }
  if(i==USER_NUM){                // 若i等于通行用户数量，则上层循环未找到通行卡。
    Serial.print("Find a unknown card, its uid:");
    for(i=0;  i<4;  i++){         // 输出此卡UID，便于后期新增通行卡。
      Serial.print(rfid.uid.uidByte[i], DEC);
      Serial.print(" ");
    }
    Serial.println();
  }

  rfid.PICC_HaltA();              // 使放置在读卡区的IC卡进入休眠状态，不再重复读卡
  rfid.PCD_StopCrypto1();         // 停止读卡模块编码

}

void servoControl(){              // 舵机控制函数。
  Serial.println("Servo run!");   // 函数运行输出标识。
  servoPulse(0);                  // 舵机转至0度。
  delay(1000);                    // 等待舵机运转。
  servoPulse(180);                // 舵机转至180度。
  servoRun = 0;                   // 舵机运行变量置零。
}

void servoPulse(int myangle)      // 定义一个脉冲函数，作者：https://blog.csdn.net/sss_369/article/details/52894347
{
  int pulseWidth=(myangle*11)+500;// 将角度转化为500-2480 的脉宽值
  digitalWrite(SERVO_PIN,HIGH);   // 将舵机接口电平至高
  delayMicroseconds(pulseWidth);  // 延时脉宽值的微秒数weimiao
  digitalWrite(SERVO_PIN,LOW);    // 将舵机接口电平至低
  delay(20-pulseWidth/1000);
}

void receiveEvent(int howMany){   // 定义接受联网信息函数，参考：https://blog.csdn.net/qq_44506730/article/details/90578507
  while(0<Wire.available()){      
    char c = Wire.read();
    if (c == '1')  servoRun = 1;  // 如果传入数据为1，则舵机运行变量置1。
    Serial.println("Receive an access sign from ESP8266.");  
  }
}

NodeMCU烧录平台

Arduino 1.8.13
开发板:NodeMCU 1.0
其余设置默认。
平台选择可看这篇：带联网功能的RFID宿舍门禁(二)-ESP8266利用arduino使用AP模式建立简单服务器

NodeMCU代码

/* 作者:MWHLS,主页MWHLS.TOP
 * 链接：http://mwhls.top/?p=659
 * 通过主机连接上ESP8266热点，进入通信网址，点击CLICK按钮后，
 * 一个消息会使用I2C通信传输给Arduino，这个消息会触发舵机转动。
 * 参考文章：
 * I2C通信：https://blog.csdn.net/qq_44506730/article/details/90578507
 * 网页控制：https://blog.csdn.net/qq_46292418/article/details/106605366
 */
#include <ESP8266WiFi.h>            // 本程序使用 ESP8266WiFi库
#include <ESP8266WebServer.h>       // ESP8266WebServer库
#include <Wire.h>                   // 使用Wire.h进行I2C通信

ESP8266WebServer esp8266_server(80);// 建立ESP8266WebServer对象，对象名称为esp8266_server
                                    // 括号中的数字是网路服务器响应http请求的端口号
                                    // 网络服务器标准http端口号为80，因此这里使用80为端口号
#define WIFISSID "ESP8266Web"       // 设定ESP8266 wifi名称
#define WIFIPSSD "123456789"        // 设定wifi密码

void setup(void){
  Serial.begin(9600);               // 启动串口通讯
  Wire.begin(D1,D2);                // I2C通信端口
  setAP();                          // 设定AP模式，并建立热点。

//--------"启动网络服务功能"程序部分开始--------           // 此部分为程序为本示例程序重点1
  esp8266_server.begin();                             // 详细讲解请参见太极创客网站《零基础入门学用物联网》
  esp8266_server.on("/", HTTP_GET, handleRoot);       // 第3章-第2节 ESP8266-NodeMCU网络服务器-1
  esp8266_server.on("/CLICK", HTTP_POST, handleClick);// 处理用户点击消息。
  esp8266_server.onNotFound(handleNotFound);          // 404处理。
//--------"启动网络服务功能"程序部分结束--------
  Serial.println("HTTP esp8266_server started");      // 告知用户ESP8266网络服务功能已经启动
}

void loop(void){
  esp8266_server.handleClient();                      // 处理http服务器访问
}

void setAP(){
  WiFi.mode(WIFI_AP);                                 // 设定ESP8266的AP模式
  WiFi.softAP(WIFISSID,WIFIPSSD);                     // 设定ESP8266热点
  Serial.printf("Success!\nWIFISSID:  %s \nWIFIPSSD:  %s \nControlWeb:  ", WIFISSID, WIFIPSSD);
  Serial.println(WiFi.softAPIP());                    // 接上行，输出WIFI信息与通信网址。
}

void handleRoot() {                                   // 处理网站根目录“/”的访问请求 
  esp8266_server.send(200, "text/html", "<form action=\"/CLICK\" method=\"POST\"><input type=\"submit\" value=\"CLICK\"></form>");
}

void handleClick(){                                   // 点击消息处理函数
  Serial.println("Click.");                           
  clickTransmission();                                // 传输点击消息到Arduino板。
  esp8266_server.sendHeader("Location","/");          // 跳转回页面根目录
  esp8266_server.send(303);                           // 发送Http相应代码303 跳转  
}

void clickTransmission(){                             // 点击消息传输函数
  Wire.beginTransmission(8);                          // 开始传输
  Wire.write('1');                                    // 传 1 至Arduino版
  Wire.endTransmission();                             // 结束传输
  Serial.println("Click transmiss success.");         // 输出成功信息
}

// 设置处理404情况的函数'handleNotFound'
void handleNotFound(){                                        // 当浏览器请求的网络资源无法在服务器找到时，
  esp8266_server.send(404, "text/plain", "404: Not found");   // NodeMCU将调用此函数。
}